'Crea un módulo nuevo y pega este código. Nombre: basActivarBotonCerrar

Option Compare Database
Option Explicit

Public Declare Function GetSystemMenu Lib "user32" (ByVal hwnd As Long, _
                                                    ByVal bRevert As Long) As Long

Public Declare Function GetMenuItemCount Lib "user32" (ByVal hMenu As Long) As Long
Public Declare Function RemoveMenu Lib "user32" (ByVal hMenu As Long, _
                                    ByVal nPosition As Long, ByVal wFlags As Long) As Long

Public Const MF_BYPOSITION = &H400&
Public Const MF_REMOVE = &H1000&

Private Sub Demomc_ActivarBotónCerrar()
    
    'Activar el botón.
   Call mc_ActivarBotónCerrar(True)
    'Desactivar el botón.
    Call mc_ActivarBotónCerrar(False)

End Sub

Public Sub mc_ActivarBotónCerrar(blnActivar As Boolean)
'********************************************************************************************
'Actualización:                                                 Fecha Creación:    21/10/2001
'Autor:             Desconocido
'Modificación:      McPegasus
'Contacto:          mcpegasus@mcpegasus.com, www.mcpegasus.com
'
'Propósito:         Para activar/desactivar el botón de  cerrar de la  ventana principal de _
                    Microsoft Access.

'La sintaxis del Procedimiento o Función, consta de estos argumentos:
'Parte                          Descripción
'-------------------------------------------------------------------------------------------
'blnActivar:         Requerido  True,   activa el botón. _
                                False,  lo desactiva.

    'Variables para desabilitar el botón cerrar de la ventana principal de Microsoft Access.
    Dim hSysMenu    As Long
    Dim nCnt        As Long
    Dim RetVal      As Long
    Dim WinWnd      As Long
    
    Dim lpClassName As String
    Dim Ret         As String
    
    'Establecer el controlador asignado por Windows de la ventana principal de Access.
    WinWnd = Application.hWndAccessApp
    'Con el parámetro true, Habilitamos el botón cerrar.
    hSysMenu = GetSystemMenu(WinWnd, blnActivar)
    
    If Not (blnActivar) Then
        If hSysMenu Then
            nCnt = GetMenuItemCount(hSysMenu)
            If nCnt Then
                RemoveMenu hSysMenu, nCnt - 1, MF_BYPOSITION Or MF_REMOVE
            End If
        End If
    End If

End Sub